#pragma rtGlobals=1		// Use modern global access method.
Window PanelCromerLiberman(): Panel

	string sFont = "Times New Roman";
	variable fSize = 14;

	if (wintype("PanelCromerLiberman") == 7)
		dowindow/f PanelCromerLiberman;
		return;
	endif;
	string savedDF=GetDataFolder(1);
	NewDataFolder/o/s root:Packages
	NewDataFolder/o/s root:Packages:CromerControl
	variable/c dummy=Get_fp("H",10);

	PauseUpdate; Silent 1
	variable/g gIndexAtom;
	variable/g gMuOverRho;
	variable/g gRadioSourceDef;
	variable/g gDeltaF1,gDeltaF2;
	variable/g gWavelength=1.5405929;
	variable/g gEnergy=12.398419/gWavelength;
	string/g sAtomName=StringFromList(gIndexAtom-1,root:Packages:CromerCalculations:ListOfElements);
	string/g sAtomicNumber=StringFromList(gIndexAtom-1,root:Packages:CromerCalculations:ListOfElNumbers);
	string/g sAtomicWeight=StringFromList(gIndexAtom-1,root:Packages:CromerCalculations:ListOfElAtomWghts);

	variable f = fSize / 12;
	variable lineHeight = fSize * 2;
	variable checkboxH = fSize * 1.5;
	variable setvarH = fSize * 1.5;
	variable popupH = fSize * 2;

	variable winWidth;
	make/o margin={(10*f),(10*f),(10*f)}
	make/o posItem={(20*f),(120*f),(300*f),(20*f),(180*f),(20*f)};
	make/o widthItem={(200*f),(100*f),(60*f),(130*f),(200*f),(200*f),(20*f)};

	winWidth=sum(margin,0,3)+sum(widthItem,0,2);
	winWidth=0;
	variable j=0,nItem=numpnts(posItem);
	do
		winWidth=max(winWidth,posItem[j]+widthItem[j]+widthItem[nItem])
		j+=1;
	while (j<nItem);
	newpanel /w=(100,50,(100+winWidth),(50+lineHeight*8)) as "Dispersion Control Panel";
	setdrawlayer UserBack;
	
	variable x0,y0;
	variable itemWidth,titleWidth;
	string sItem,sTitle;

	y0=lineHeight*0.5;
	//*** title text ***//
	x0=posItem[0];
	setdrawenv fsize=(fSize),fstyle=1,fname=$sFont //,fname="Times";
	drawtext (x0),(y0+11),"Dispersion Properties based on Cromer-Liberman method";

	y0+=lineHeight;

	//*** radio buttons ***//
	x0=posItem[0];
	itemWidth=widthItem[0]; titleWidth=40*f;
	sItem="radioUseWavelength";
	sTitle="Wavelength [A] :";
	CheckBox $sItem,pos={(x0),(y0)},size={(itemWidth),(checkboxH)};
	CheckBox $sItem,proc=RadioSourceDefProc;
	CheckBox $sItem,fsize=(fSize), font=$sFont;
	CheckBox $sItem,title=(sTitle),mode=1,value=(gRadioSourceDef==0);
	sItem="radioUseEnergy";
	sTitle="Energy [keV] :";
	CheckBox $sItem,pos={(x0),(y0+lineHeight)},size={(itemWidth),(checkboxH)};
	CheckBox $sItem,proc=RadioSourceDefProc;
	CheckBox $sItem,fsize=(fSize), font=$sFont;
	CheckBox $sItem,title=(sTitle),mode=1,value=(gRadioSourceDef==1);

	//*** Set variables ***//
	x0=posItem[1];
	itemWidth=widthItem[1];
	sItem="setvarWavelength";
	sTitle=" ";
	SetVariable $sItem,pos={(x0),(y0)},size={(itemWidth),(setvarH)};
	SetVariable $sItem,bodyWidth=(itemWidth*0.9),fsize=(fSize),font=$sFont;
	SetVariable $sItem,limits={0.5,2.0,0.000001},value=gWavelength,title=(sTitle);
	SetVariable $sItem,format="%11.7f",proc=SetVarEnergyOrWavelength;
	sItem="setvarEnergy";
	SetVariable $sItem,pos={(x0),(y0+lineHeight)},size={(itemWidth),(setvarH)};
	SetVariable $sItem,bodyWidth=(itemWidth*0.9),fsize=(fSize),font=$sFont;
	SetVariable $sItem,limits={6,25,0.01},value=gEnergy,title=(sTitle);
	SetVariable $sItem,format="%10.6f",proc=SetVarEnergyOrWavelength;

	//*** PopupAtomList ***//
	variable items=ItemsInList(root:Packages:CromerCalculations:ListOfElements);
	x0=posItem[2];
	itemWidth=widthItem[2]
	sItem="popupAtomList";
	sTitle="Atom :";
	PopupMenu $sItem,bodyWidth=(itemWidth),disable=0,fsize=(fSize),font=$sFont;
	PopupMenu $sItem,mode=1,pos={(x0),(y0+lineHeight*0.5)};
	PopupMenu $sItem,title=(sTitle),value=(root:Packages:CromerCalculations:ListOfElements);
	PopupMenu $sItem,mode=(gIndexAtom+1);
	PopupMenu $sItem,proc=PopupAtomProc;

	y0+=lineHeight*2;
	//*** Draw horizontal line ***//
	Drawline (posItem[0]),(y0+lineHeight*0.5),(winWidth-widthItem[nItem]),(y0+lineHeight*0.5);

	y0+=lineHeight;
	//*** Setvariables, used for displaying values ***//
	x0=posItem[3];
	itemWidth=widthItem[3];
	sItem="setvarDeltaF1";
	sTitle="Delta f1 :";
	SetVariable $sItem,pos={(x0),(y0)},size={(itemWidth),(setvarH)};
	SetVariable $sItem,bodyWidth=(itemWidth*0.6),fsize=(fSize),font=$sFont;;
	SetVariable $sItem,value=gDeltaF1,noproc,title=(sTitle);
	SetVariable $sItem,format="%8.3f",limits={0,0,0};
	sItem="setvarDeltaF2";
	sTitle="Delta f2 :";
	SetVariable $sItem,pos={(x0),(y0+lineHeight)},size={(itemWidth),(setvarH)};
	SetVariable $sItem,bodyWidth=(itemWidth*0.6),fsize=(fSize),font=$sFont;
	SetVariable $sItem,value=gDeltaF2,noproc,title=(sTitle);
	SetVariable $sItem,format="%8.3f",limits={0,0,0};

	//*** Atomic Number and Weight ***//
	x0=posItem[4];
	itemWidth=widthItem[4];
	sItem="setvarAtomNumber";
	sTitle="Atomic number : ";
	SetVariable $sItem,pos={(x0),(y0)},size={(itemWidth),(setvarH)};
	SetVariable $sItem,bodyWidth=(itemWidth*0.5),fsize=(fSize),font=$sFont;
	SetVariable $sItem,value=sAtomicNumber,noproc,title=(sTitle);
	SetVariable $sItem,format="%g";
	sItem="setvarAtomWeight";
	sTitle="Atomic weight : ";
	SetVariable $sItem,pos={(x0),(y0+lineHeight)},size={(itemWidth),(setvarH)};
	SetVariable $sItem,bodyWidth=(itemWidth*0.5),fsize=(fsize),font=$sFont;
	SetVariable $sItem,value=sAtomicWeight,noproc,title=(sTitle);
	SetVariable $sItem,format="%g";
	 y0+=lineHeight*2;
	 x0=posItem[5];
	 itemWidth=widthItem[5];
	sItem="setvarMuOverRho";
	sTitle="mu / rho  [cm^2/g]:";
	SetVariable $sItem,pos={(x0),(y0)},size={(itemWidth),(setvarH)};
	SetVariable $sItem,bodyWidth=(itemWidth*0.4),fsize=(fSize),font=$sFont;
	SetVariable $sItem,value=gMuOverRho,noproc,title=(sTitle);
	SetVariable $sItem,format="%g",limits={0,0,0};
	SetDataFolder savedDF;
end;

function RadioSourceDefProc(ctrlName,checked) : CheckBoxControl
	string ctrlName; variable checked;
	svar sAtomName=root:Packages:CromerControl:sAtomName;
	nvar gRadioSourceDef=root:Packages:CromerControl:gRadioSourceDef;
	nvar gWavelength=root:Packages:CromerControl:gWavelength;
	nvar gEnergy=root:Packages:CromerControl:gEnergy;
	strswitch(ctrlName)
		case "radioUseWavelength":
			gRadioSourceDef=0;
			gEnergy=12.398419/gWavelength;
			break;
		case "radioUseEnergy":
			gRadioSourceDef=1;
			gWavelength=12.398419/gEnergy;
			break;
	endswitch;
	UpdateCromerControl(sAtomName,gEnergy);
end;

Function PopupAtomProc(ctrlName,popNum,popStr) : PopupMenuControl
	String ctrlName
	Variable popNum	// which item is currently selected (1-based)
	String popStr		// contents of current popup item as string
	string savedDF=GetDataFolder(1);
	SetDataFolder root:Packages:CromerControl;
	nvar gEnergy,gDeltaF1,gDeltaF2,gIndexAtom,gMuOverRho;
	svar sNumber=sAtomicNumber,sWeight=sAtomicWeight,sAtomName;
	svar sElementList=root:Packages:CromerCalculations:ListOfElements;
	svar sNumberList=root:Packages:CromerCalculations:ListOfElNumbers;
	svar sWeightList=root:Packages:CromerCalculations:ListOfElAtomWghts;
	string sBuf;
	variable/c f;
	f=Get_fp(popStr,gEnergy);
	gDeltaF1=real(f);
	gDeltaF2=imag(f);
	gIndexAtom=WhichListItem(popStr,sElementList);
	sAtomName=StringFromList(gIndexAtom-1,sElementList);
	sNumber=StringFromList(gIndexAtom-1,sNumberList);
	sWeight=StringFromList(gIndexAtom-1,sWeightList);
	gMuOverRho=Get_MuOverRho(popStr,gEnergy);
	doupdate;
	SetDataFolder savedDF;
End

Function SetVarEnergyOrWavelength(ctrlName,varNum,varStr,varName):SetVariableControl
	string ctrlName;
	variable varNum;	// value of variable as number
	string varStr;	//value of variable as string
	string varName	// name of variable;
	nvar gEnergy=root:Packages:CromerControl:gEnergy;
	nvar gWavelength=root:Packages:CromerControl:gWavelength;
	nvar gRadioSourceDef=root:Packages:CromerControl:gRadioSourceDef;
	svar sAtomName=root:Packages:CromerControl:sAtomName;
	if (cmpstr(ctrlName,"setvarWavelength")==0)
		gEnergy=12.398419/gWavelength;
		gRadioSourceDef=0;
	else
		gWavelength=12.398419/gEnergy;
		gRadioSourceDef=1;
	endif;
	UpdateCromerControl(sAtomName,gEnergy);
end;

static function UpdateCromerControl(sAtom,keV)
	string sAtom;	variable keV;
	string savedDF=GetDataFolder(1);
	SetDataFolder root:Packages:CromerControl;
	nvar gDeltaF1,gDeltaF2,gRadioSourceDef;
	variable/c f;
	f=Get_fp(sAtom,keV);
	gDeltaF1=real(f);
	gDeltaF2=imag(f);
	CheckBox radioUseWavelength,value=(gRadioSourceDef==0);
	CheckBox radioUseEnergy,value=(gRadioSourceDef==1);
	SetDataFolder savedDF;
end;